[CMake] work by Julien Cristau

This is a combination of 18 commits.
replace Makefile with CMakeLists for camera/simulator
lima<module>.sip needs to import limacore.sip

.gitignore

@@ -23,4 +23,6 @@ install
 /.cproject
 /.pydevproject
 /.settings
-
+CMakeCache.txt
+CMakeFiles/
+cmake_install.cmake

CMakeLists.txt

+
+cmake_minimum_required(VERSION 2.8)
+project (lima)
+
+SET(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake ${CMAKE_MODULE_PATH})
+FIND_PACKAGE(PythonInterp 2.7)
+FIND_PACKAGE(PythonLibs 2.7)
+IF (${PYTHONINTERP_FOUND})
+    # python site-packages folder
+    execute_process(
+       COMMAND ${PYTHON_EXECUTABLE} -c "from distutils.sysconfig import get_python_lib; print get_python_lib()"
+       OUTPUT_VARIABLE _PYTHON_SITE_PACKAGES_DIR OUTPUT_STRIP_TRAILING_WHITESPACE)
+ENDIF()
+FIND_PACKAGE(SIP)
+INCLUDE(SIPMacros)
+
+SET(PYTHON_SITE_PACKAGES_DIR ${_PYTHON_SITE_PACKAGES_DIR} CACHE PATH "where should python modules be installed?")
+
+find_package(Threads REQUIRED)
+
+set(CMAKE_SHARED_LINKER_FLAGS "-Wl,--no-undefined")
+
+set(COMPILE_CORE ON CACHE BOOL "compile core?")
+set(COMPILE_SIMULATOR ON CACHE BOOL "compile simulator?")
+set(COMPILE_SPS_IMAGE ON CACHE BOOL "compile sps_image?")
+set(COMPILE_BASLER ON CACHE BOOL "compile basler?")
+set(COMPILE_SIP OFF CACHE BOOL "compile python modules?")
+set(COMPILE_TIFF_SAVING OFF CACHE BOOL "compile tiff saving code?")
+
+if(COMPILE_SIP)
+    IF(!${SIP_FOUND})
+        MESSAGE(FATAL_ERROR "sip executable not found, cannot build python extensions")
+    ENDIF()
+    if (WIN32)
+        set(SIP_TAGS WIN32_PLATFORM)
+    elseif(UNIX)
+        set(SIP_TAGS POSIX_PLATFORM)
+    endif(WIN32)
+    set(SIP_EXTRA_OPTIONS -e -g)
+endif(COMPILE_SIP)
+
+add_subdirectory(third-party/Processlib)
+
+set(common_srcs common/src/Constants.cpp common/src/SizeUtils.cpp common/src/Timestamp.cpp common/src/ThreadUtils.cpp
+                common/src/Exceptions.cpp common/src/MemUtils.cpp common/src/RegExUtils.cpp common/src/AcqState.cpp
+                common/src/Debug.cpp common/src/VideoUtils.cpp common/src/Event.cpp common/src/Timer.cpp
+                common/src/DirectoryEventUtils.cpp)
+#if (0 and COMPILE_CONFIG)
+#    set(config_objs common/src/ConfigUtils.cpp)
+#endif (0 and COMPILE_CONFIG)
+
+set(hw_srcs hardware/src/HwInterface.cpp hardware/src/HwCap.cpp hardware/src/HwSyncCtrlObj.cpp hardware/src/HwFrameInfo.cpp
+            hardware/src/HwFrameCallback.cpp hardware/src/HwBufferCtrlObj.cpp hardware/src/HwBufferMgr.cpp
+            hardware/src/HwShutterCtrlObj.cpp hardware/src/HwMaxImageSizeCallback.cpp hardware/src/HwDetInfoCtrlObj.cpp
+            hardware/src/HwBinCtrlObj.cpp hardware/src/HwRoiCtrlObj.cpp hardware/src/HwFlipCtrlObj.cpp hardware/src/HwSerialLine.cpp
+            hardware/src/HwBufferSave.cpp hardware/src/HwVideoCtrlObj.cpp hardware/src/HwEventCtrlObj.cpp hardware/src/HwSavingCtrlObj.cpp
+            hardware/src/HwFileEventMgr.cpp hardware/src/HwReconstructionCtrlObj.cpp)
+
+set(control_srcs control/src/CtSaving.cpp control/src/CtControl.cpp control/src/CtAcquisition.cpp control/src/CtBuffer.cpp
+                 control/src/CtImage.cpp control/src/CtSaving_Edf.cpp control/src/CtShutter.cpp control/src/CtAccumulation.cpp control/src/CtVideo.cpp
+                 control/src/CtEvent.cpp)
+set(ct_srcs control/software_operation/src/SoftOpInternalMgr.cpp control/software_operation/src/SoftOpExternalMgr.cpp control/software_operation/src/SoftOpId.cpp)
+
+if(COMPILE_SPS_IMAGE)
+    add_definitions(-DWITH_SPS_IMAGE)
+    set(ct_srcs ${ct_srcs} control/src/CtSpsImage.cpp third-party/Sps/Src/sps.c)
+endif()
+if(COMPILE_TIFF_SAVING)
+    add_definitions(-DWITH_TIFF_SAVING)
+    set(ct_srcs ${ct_srcs} control/src/CtSaving_Tiff.cpp)
+endif()
+
+file(STRINGS "common/VERSION" core_ver)
+add_library(limacore SHARED
+    ${common_srcs}
+    ${hw_srcs}
+    ${control_srcs}
+    ${ct_srcs}
+)
+TARGET_INCLUDE_DIRECTORIES(limacore PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}/common/include")
+TARGET_INCLUDE_DIRECTORIES(limacore PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}/hardware/include")
+TARGET_INCLUDE_DIRECTORIES(limacore PUBLIC
+    "${CMAKE_CURRENT_SOURCE_DIR}/control/include"
+    "${CMAKE_CURRENT_SOURCE_DIR}/control/software_operation/include")
+TARGET_INCLUDE_DIRECTORIES(limacore PUBLIC
+    "${CMAKE_CURRENT_SOURCE_DIR}/third-party/Processlib/core/include"
+    "${CMAKE_CURRENT_SOURCE_DIR}/third-party/Processlib/tasks/include")
+if(COMPILE_SPS_IMAGE)
+    target_include_directories(limacore PRIVATE "${CMAKE_SOURCE_DIR}/third-party/Sps/Include")
+endif()
+if(COMPILE_TIFF_SAVING)
+    target_link_libraries(limacore -ltiff)
+endif()
+if(THREADS_HAVE_PTHREAD_ARG)
+    target_compile_options(PUBLIC limacore "-pthread")
+endif()
+if(CMAKE_THREAD_LIBS_INIT)
+    target_link_libraries(limacore "${CMAKE_THREAD_LIBS_INIT}")
+endif()
+TARGET_LINK_LIBRARIES(limacore "rt")
+TARGET_LINK_LIBRARIES(limacore processlib)
+SET_TARGET_PROPERTIES(limacore PROPERTIES VERSION ${core_ver} SOVERSION "1")
+INSTALL(TARGETS limacore
+        LIBRARY DESTINATION lib
+        PUBLIC_HEADER DESTINATION include)
+
+if(COMPILE_SIMULATOR)
+    add_subdirectory(camera/simulator)
+endif(COMPILE_SIMULATOR)
+if(COMPILE_BASLER)
+    add_subdirectory(camera/basler)
+endif(COMPILE_BASLER)
+
+if(COMPILE_SIP)
+    set(NAME "core")
+    set(INCLUDES)
+    FILE(GLOB sipfiles
+         RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}/common/sip"
+         "${CMAKE_CURRENT_SOURCE_DIR}/common/sip/*.sip"
+         RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}/hardware/sip"
+         "${CMAKE_CURRENT_SOURCE_DIR}/hardware/sip/*.sip"
+         RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}/control/sip"
+         "${CMAKE_CURRENT_SOURCE_DIR}/control/sip/*.sip"
+         RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}/control/software_operation/sip"
+         "${CMAKE_CURRENT_SOURCE_DIR}/control/software_operation/sip/*.sip")
+    FOREACH(sipfile ${sipfiles})
+        set(INCLUDES
+"${INCLUDES}
+%Include ${sipfile}"
+)
+    ENDFOREACH()
+
+    configure_file(sip/core/limacore.sip.in sip/core/limacore.sip)
+    set(SIP_CONCAT_PARTS 1)
+    set(SIP_INCLUDES ${SIP_INCLUDES}
+        "${CMAKE_CURRENT_SOURCE_DIR}/third-party/Processlib/sip"
+        "${CMAKE_CURRENT_SOURCE_DIR}/third-party/Processlib/tasks/sip"
+        "${CMAKE_CURRENT_SOURCE_DIR}/common/sip"
+        "${CMAKE_CURRENT_SOURCE_DIR}/hardware/sip"
+        "${CMAKE_CURRENT_SOURCE_DIR}/control/sip"
+        "${CMAKE_CURRENT_SOURCE_DIR}/control/software_operation/sip")
+    set(SIP_DISABLE_FEATURES WITH_CONFIG)
+    set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/sip/core/limacore.sip PROPERTIES OBJECT_DEPENDS ${sipfiles})
+    ADD_SIP_PYTHON_MODULE(limacore ${CMAKE_CURRENT_BINARY_DIR}/sip/core/limacore.sip)
+    #ADD_SIP_PYTHON_MODULE(limacore sip/core/limacore.sip)
+    TARGET_INCLUDE_DIRECTORIES(python_module_limacore PRIVATE
+        ${PYTHON_INCLUDE_DIRS}
+        ${CMAKE_CURRENT_SOURCE_DIR}/sip
+        ${CMAKE_CURRENT_SOURCE_DIR}/sip/core
+        ${CMAKE_CURRENT_SOURCE_DIR}/third-party/Processlib/sip)
+    TARGET_LINK_LIBRARIES(python_module_limacore limacore)
+
+    INSTALL(FILES python/__init__.py DESTINATION "${PYTHON_SITE_PACKAGES_DIR}/Lima")
+    INSTALL(FILES common/python/__init__.py common/python/Debug.py DESTINATION "${PYTHON_SITE_PACKAGES_DIR}/Lima/Core")
+endif(COMPILE_SIP)

Makefile

-##############################################################################
-#
-# This file is part of LImA, a Library for Image Acquisition
-#
-# Copyright (C) : 2009-2011
-# European Synchrotron Radiation Facility
-# BP 220, Grenoble 38043
-# FRANCE
-#
-# This is free software; you can redistribute it and/or modify
-# it under the terms of the GNU General Public License as published by
-# the Free Software Foundation; either version 3 of the License, or
-# (at your option) any later version.
-#
-# This software is distributed in the hope that it will be useful,
-# but WITHOUT ANY WARRANTY; without even the implied warranty of
-# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
-# GNU General Public License for more details.
-#
-# You should have received a copy of the GNU General Public License
-# along with this program; if not, see <http://www.gnu.org/licenses/>.
-############################################################################
-
-.NOTPARALLEL:
-
-sub-dirs = third-party common hardware control camera build
-
-all:	src test
-
-include config.inc
-
-include global.inc
-
-config.inc:
-	@echo "*** Creating default \"config.inc\" with LImA core"
-	@echo "*** Please edit it to activate compilation of hardware modules"
-	cp config.inc_default config.inc
-	@false
-
-config:
-	$(MAKE) -C third-party prelima.config
-	$(MAKE) -C sip config
-	$(MAKE) -C third-party postlima.config
-
-include install.inc
-

camera/simulator/CMakeLists.txt

+
+SET(simu_srcs src/SimulatorFrameBuilder.cpp src/SimulatorCamera.cpp src/SimulatorInterface.cpp
+              src/SimulatorSyncCtrlObj.cpp src/SimulatorDetInfoCtrlObj.cpp src/SimulatorShutterCtrlObj.cpp)
+
+FILE(STRINGS "VERSION" simu_ver)
+ADD_LIBRARY(limasimulator SHARED
+    ${simu_srcs}
+)
+TARGET_INCLUDE_DIRECTORIES(limasimulator PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}/include")
+TARGET_INCLUDE_DIRECTORIES(limasimulator PRIVATE "${CMAKE_CURRENT_SOURCE_DIR}/../../common/include")
+TARGET_INCLUDE_DIRECTORIES(limasimulator PRIVATE "${CMAKE_CURRENT_SOURCE_DIR}/../../hardware/include")
+TARGET_LINK_LIBRARIES(limasimulator limacore)
+SET_TARGET_PROPERTIES(limasimulator PROPERTIES VERSION ${simu_ver} SOVERSION "1")
+INSTALL(TARGETS limasimulator
+        LIBRARY DESTINATION lib)
+
+IF (COMPILE_SIP)
+    SET(NAME "simulator")
+    SET(INCLUDES)
+    FILE(GLOB sipfiles
+         RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}/sip"
+         "${CMAKE_CURRENT_SOURCE_DIR}/sip/*.sip")
+    FOREACH(sipfile ${sipfiles})
+        SET(INCLUDES
+"${INCLUDES}
+%Include ${sipfile}"
+)
+    ENDFOREACH()
+
+    CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/sip/limamodules.sip.in sip/limasimulator.sip)
+    SET(SIP_INCLUDES ${SIP_INCLUDES}
+        "${CMAKE_SOURCE_DIR}/third-party/Processlib/sip"
+        "${CMAKE_BINARY_DIR}/sip/core"
+        "${CMAKE_SOURCE_DIR}/third-party/Processlib/tasks/sip"
+        "${CMAKE_SOURCE_DIR}/common/sip"
+        "${CMAKE_SOURCE_DIR}/hardware/sip"
+        "${CMAKE_SOURCE_DIR}/control/sip"
+        "${CMAKE_SOURCE_DIR}/control/software_operation/sip"
+        "${CMAKE_CURRENT_SOURCE_DIR}/sip")
+    SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_BINARY_DIR}/sip/limasimulator.sip PROPERTIES OBJECT_DEPENDS ${sipfiles})
+    ADD_SIP_PYTHON_MODULE(limasimulator ${CMAKE_CURRENT_BINARY_DIR}/sip/limasimulator.sip)
+    TARGET_INCLUDE_DIRECTORIES(python_module_limasimulator PRIVATE
+                               ${PYTHON_INCLUDE_DIRS}
+                               "${CMAKE_SOURCE_DIR}/sip"
+                               "${CMAKE_SOURCE_DIR}/sip/core"
+                              )
+    TARGET_LINK_LIBRARIES(python_module_limasimulator limasimulator)
+    INSTALL(FILES python/__init__.py DESTINATION "${PYTHON_SITE_PACKAGES_DIR}/Lima/Simulator")
+ENDIF()

camera/simulator/Makefile

-############################################################################
-# This file is part of LImA, a Library for Image Acquisition
-#
-# Copyright (C) : 2009-2011
-# European Synchrotron Radiation Facility
-# BP 220, Grenoble 38043
-# FRANCE
-#
-# This is free software; you can redistribute it and/or modify
-# it under the terms of the GNU General Public License as published by
-# the Free Software Foundation; either version 3 of the License, or
-# (at your option) any later version.
-#
-# This software is distributed in the hope that it will be useful,
-# but WITHOUT ANY WARRANTY; without even the implied warranty of
-# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
-# GNU General Public License for more details.
-#
-# You should have received a copy of the GNU General Public License
-# along with this program; if not, see <http://www.gnu.org/licenses/>.
-############################################################################
-src-dirs  = src
-test-dirs = test
-
-include ../../global.inc

camera/simulator/python/__init__.py

@@ -19,23 +19,7 @@
 # You should have received a copy of the GNU General Public License
 # along with this program; if not, see <http://www.gnu.org/licenses/>.
 ############################################################################
-from Lima import module_helper
-
-mod_path = __path__
-depends_on = 'Core'
-has_dependent = False
-
-cleanup_data = module_helper.load_prepare(mod_path, depends_on, has_dependent)
-
 from Lima import Core
 
-cleanup_data = module_helper.load_dep_cleanup(cleanup_data)
-
-from Lima.Simulator.limasimulator import Simulator as _S
+from limasimulator import Simulator as _S
 globals().update(_S.__dict__)
-
-module_helper.load_cleanup(cleanup_data)
-
-del mod_path, depends_on, has_dependent, cleanup_data
-del module_helper
-

cmake/FindSIP.cmake

+# Find SIP
+# ~~~~~~~~
+#
+# SIP website: http://www.riverbankcomputing.co.uk/sip/index.php
+#
+# Find the installed version of SIP. FindSIP should be called after Python
+# has been found.
+#
+# This file defines the following variables:
+#
+# SIP_VERSION - The version of SIP found expressed as a 6 digit hex number
+#     suitable for comparision as a string.
+#
+# SIP_VERSION_STR - The version of SIP found as a human readable string.
+#
+# SIP_EXECUTABLE - Path and filename of the SIP command line executable.
+#
+# SIP_INCLUDE_DIR - Directory holding the SIP C++ header file.
+#
+# SIP_DEFAULT_SIP_DIR - Default directory where .sip files should be installed
+#     into.
+
+# Copyright (c) 2007, Simon Edwards <simon@simonzone.com>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+
+
+IF(SIP_VERSION)
+  # Already in cache, be silent
+  SET(SIP_FOUND TRUE)
+ELSE(SIP_VERSION)
+
+  FIND_FILE(_find_sip_py FindSIP.py PATHS ${CMAKE_MODULE_PATH})
+
+  EXECUTE_PROCESS(COMMAND ${PYTHON_EXECUTABLE} ${_find_sip_py} OUTPUT_VARIABLE sip_config)
+  IF(sip_config)
+    STRING(REGEX REPLACE "^sip_version:([^\n]+).*$" "\\1" SIP_VERSION ${sip_config})
+    STRING(REGEX REPLACE ".*\nsip_version_str:([^\n]+).*$" "\\1" SIP_VERSION_STR ${sip_config})
+    STRING(REGEX REPLACE ".*\nsip_bin:([^\n]+).*$" "\\1" SIP_EXECUTABLE ${sip_config})
+    STRING(REGEX REPLACE ".*\ndefault_sip_dir:([^\n]+).*$" "\\1" SIP_DEFAULT_SIP_DIR ${sip_config})
+    STRING(REGEX REPLACE ".*\nsip_inc_dir:([^\n]+).*$" "\\1" SIP_INCLUDE_DIR ${sip_config})
+    SET(SIP_FOUND TRUE)
+  ENDIF(sip_config)
+
+  IF(SIP_FOUND)
+    IF(NOT SIP_FIND_QUIETLY)
+      MESSAGE(STATUS "Found SIP version: ${SIP_VERSION_STR}")
+    ENDIF(NOT SIP_FIND_QUIETLY)
+  ELSE(SIP_FOUND)
+    IF(SIP_FIND_REQUIRED)
+      MESSAGE(FATAL_ERROR "Could not find SIP")
+    ENDIF(SIP_FIND_REQUIRED)
+  ENDIF(SIP_FOUND)
+
+ENDIF(SIP_VERSION)

cmake/FindSIP.py

+# FindSIP.py
+#
+# Copyright (c) 2007, Simon Edwards <simon@simonzone.com>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+import sys
+import sipconfig
+
+sipcfg = sipconfig.Configuration()
+print("sip_version:%06.0x" % sipcfg.sip_version)
+print("sip_version_str:%s" % sipcfg.sip_version_str)
+print("sip_bin:%s" % sipcfg.sip_bin)
+print("default_sip_dir:%s" % sipcfg.default_sip_dir)
+print("sip_inc_dir:%s" % sipcfg.sip_inc_dir)

cmake/SIPMacros.cmake

+# Macros for SIP
+# ~~~~~~~~~~~~~~
+# Copyright (c) 2007, Simon Edwards <simon@simonzone.com>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+#
+# SIP website: http://www.riverbankcomputing.co.uk/sip/index.php
+#
+# This file defines the following macros:
+#
+# ADD_SIP_PYTHON_MODULE (MODULE_NAME MODULE_SIP [library1, libaray2, ...])
+#     Specifies a SIP file to be built into a Python module and installed.
+#     MODULE_NAME is the name of Python module including any path name. (e.g.
+#     os.sys, Foo.bar etc). MODULE_SIP the path and filename of the .sip file
+#     to process and compile. libraryN are libraries that the Python module,
+#     which is typically a shared library, should be linked to. The built
+#     module will also be install into Python's site-packages directory.
+#
+# The behaviour of the ADD_SIP_PYTHON_MODULE macro can be controlled by a
+# number of variables:
+#
+# SIP_INCLUDES - List of directories which SIP will scan through when looking
+#     for included .sip files. (Corresponds to the -I option for SIP.)
+#
+# SIP_TAGS - List of tags to define when running SIP. (Corresponds to the -t
+#     option for SIP.)
+#
+# SIP_CONCAT_PARTS - An integer which defines the number of parts the C++ code
+#     of each module should be split into. Defaults to 8. (Corresponds to the
+#     -j option for SIP.)
+#
+# SIP_DISABLE_FEATURES - List of feature names which should be disabled
+#     running SIP. (Corresponds to the -x option for SIP.)
+#
+# SIP_EXTRA_OPTIONS - Extra command line options which should be passed on to
+#     SIP.
+
+SET(SIP_INCLUDES)
+SET(SIP_TAGS)
+SET(SIP_CONCAT_PARTS 8)
+SET(SIP_DISABLE_FEATURES)
+SET(SIP_EXTRA_OPTIONS)
+
+MACRO(ADD_SIP_PYTHON_MODULE MODULE_NAME MODULE_SIP)
+
+    SET(EXTRA_LINK_LIBRARIES ${ARGN})
+
+    STRING(REPLACE "." "/" _x ${MODULE_NAME})
+    GET_FILENAME_COMPONENT(_parent_module_path ${_x}  PATH)
+    GET_FILENAME_COMPONENT(_child_module_name ${_x} NAME)
+
+    GET_FILENAME_COMPONENT(_module_path ${MODULE_SIP} PATH)
+    GET_FILENAME_COMPONENT(_abs_module_sip ${MODULE_SIP} ABSOLUTE)
+
+    # We give this target a long logical target name.
+    # (This is to avoid having the library name clash with any already
+    # install library names. If that happens then cmake dependancy
+    # tracking get confused.)
+    STRING(REPLACE "." "_" _logical_name ${MODULE_NAME})
+    SET(_logical_name "python_module_${_logical_name}")
+
+    FILE(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${_module_path})    # Output goes in this dir.
+
+    SET(_sip_includes)
+    FOREACH (_inc ${SIP_INCLUDES})
+        GET_FILENAME_COMPONENT(_abs_inc ${_inc} ABSOLUTE)
+        LIST(APPEND _sip_includes -I ${_abs_inc})
+    ENDFOREACH (_inc )
+
+    SET(_sip_tags)
+    FOREACH (_tag ${SIP_TAGS})
+        LIST(APPEND _sip_tags -t ${_tag})
+    ENDFOREACH (_tag)
+
+    SET(_sip_x)
+    FOREACH (_x ${SIP_DISABLE_FEATURES})
+        LIST(APPEND _sip_x -x ${_x})
+    ENDFOREACH (_x ${SIP_DISABLE_FEATURES})
+
+    SET(_message "-DMESSAGE=Generating CPP code for module ${MODULE_NAME}")
+    SET(_sip_output_files)
+    FOREACH(CONCAT_NUM RANGE 0 ${SIP_CONCAT_PARTS} )
+        IF( ${CONCAT_NUM} LESS ${SIP_CONCAT_PARTS} )
+            SET(_sip_output_files ${_sip_output_files} ${CMAKE_CURRENT_BINARY_DIR}/${_module_path}/sip${_child_module_name}part${CONCAT_NUM}.cpp )
+        ENDIF( ${CONCAT_NUM} LESS ${SIP_CONCAT_PARTS} )
+    ENDFOREACH(CONCAT_NUM RANGE 0 ${SIP_CONCAT_PARTS} )
+
+    IF(NOT WIN32)
+        SET(TOUCH_COMMAND touch)
+    ELSE(NOT WIN32)
+        SET(TOUCH_COMMAND echo)
+        # instead of a touch command, give out the name and append to the files
+        # this is basically what the touch command does.
+        FOREACH(filename ${_sip_output_files})
+            FILE(APPEND filename "")
+        ENDFOREACH(filename ${_sip_output_files})
+    ENDIF(NOT WIN32)
+    ADD_CUSTOM_COMMAND(
+        OUTPUT ${_sip_output_files} 
+        COMMAND ${CMAKE_COMMAND} -E echo ${message}
+        COMMAND ${TOUCH_COMMAND} ${_sip_output_files} 
+        COMMAND ${SIP_EXECUTABLE} ${_sip_tags} ${_sip_x} ${SIP_EXTRA_OPTIONS} -j ${SIP_CONCAT_PARTS} -c ${CMAKE_CURRENT_BINARY_DIR}/${_module_path} ${_sip_includes} ${_abs_module_sip}
+        DEPENDS ${_abs_module_sip} ${SIP_EXTRA_FILES_DEPEND}
+    )
+    # not sure if type MODULE could be uses anywhere, limit to cygwin for now
+    IF (CYGWIN)
+        ADD_LIBRARY(${_logical_name} MODULE ${_sip_output_files} )
+    ELSE (CYGWIN)
+        ADD_LIBRARY(${_logical_name} SHARED ${_sip_output_files} )
+    ENDIF (CYGWIN)
+    TARGET_LINK_LIBRARIES(${_logical_name} ${PYTHON_LIBRARY})
+    TARGET_LINK_LIBRARIES(${_logical_name} ${EXTRA_LINK_LIBRARIES})
+    SET_TARGET_PROPERTIES(${_logical_name} PROPERTIES PREFIX "" OUTPUT_NAME ${_child_module_name})
+    
+    IF (WIN32)
+      SET_TARGET_PROPERTIES(${_logical_name} PROPERTIES SUFFIX ".pyd")
+    ENDIF (WIN32)
+
+    INSTALL(TARGETS ${_logical_name} DESTINATION "${PYTHON_SITE_PACKAGES_DIR}/${_parent_module_path}")
+
+ENDMACRO(ADD_SIP_PYTHON_MODULE)

common/python/__init__.py

@@ -19,19 +19,7 @@
 # You should have received a copy of the GNU General Public License
 # along with this program; if not, see <http://www.gnu.org/licenses/>.
 ############################################################################
-from Lima import module_helper
-
-mod_path = __path__
-depends_on = None
-has_dependent = True
-
-cleanup_data = module_helper.load_prepare(mod_path, depends_on, has_dependent)
 
 import processlib as Processlib
 from limacore import *
 from Debug import *
-
-module_helper.load_cleanup(cleanup_data)
-
-del mod_path, depends_on, has_dependent, cleanup_data
-del module_helper

common/sip/Debug.sip

@@ -64,6 +64,14 @@ enum DebModule {
 
 typedef const char *ConstStr;
 
+%UnitCode
+#include <string>
+
+static const char *getConstStr(const std::string *s)
+{
+	return (!s || s->empty()) ? NULL : s->c_str();
+}
+%End
 
 /*------------------------------------------------------------------
  *  class DebParams 
@@ -79,11 +87,6 @@ using namespace lima;
 
 %TypeCode
 
-static ConstStr getConstStr(const std::string *s)
-{
-	return (!s || s->empty()) ? NULL : s->c_str();
-}
-
 class DebParamsData
 {
 public:
@@ -204,11 +207,6 @@ using namespace lima;
 
 %TypeCode
 
-static ConstStr getConstStr(const std::string *s)
-{
-	return (!s || s->empty()) ? NULL : s->c_str();
-}
-
 class DebObjData
 {
 public:

sip/core/limacore.sip → sip/core/limacore.sip.in

@@ -515,10 +515,14 @@ return aReturnListPt;
 %End
 };
 
-%ModuleHeaderCode
-extern "C" { void lima_import_array();}
+%UnitCode
+#include <lima_init_numpy.cpp>
 %End
 
 %PostInitialisationCode
 lima_import_array();
 %End
+
+%Import processlib.sip
+
+@INCLUDES@

sip/limamodules.sip.in

-%Module(name=lima%NAME,version=0)
+%Module(name=lima@NAME@,version=0)
 
-%ModuleHeaderCode
-extern "C" { void lima_import_array();}
+%ModuleCode
+#include <lima_init_numpy.cpp>
 %End
 
 %PostInitialisationCode
 lima_import_array();
 %End
+
+%Import limacore.sip
+
+@INCLUDES@